hue.frag

Go to the documentation of this file.

#version 400  

out vec4 color;

in vec3 position;

uniform sampler3D volume;
uniform float regionSeperator;
uniform int depth;
uniform int width;
uniform int height;
uniform vec4 regionColor1;
uniform vec4 regionColor2;
uniform int orientation; // 0 top, 1 bottom, 2 left, 3 right, 4 front, 5 back

// RGBtoHSV conversion from http://lolengine.net/blog/2013/07/27/rgb-to-hsv-in-glsl
vec3 rgb2hsv(vec3 c)
{
    vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
    vec4 p = mix(vec4(c.bg, K.wz), vec4(c.gb, K.xy), step(c.b, c.g));
    vec4 q = mix(vec4(p.xyw, c.r), vec4(c.r, p.yzx), step(p.x, c.r));

    float d = q.x - min(q.w, q.y);
    float e = 1.0e-10;
    return vec3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
}
// HSVtoRGB conversion from http://lolengine.net/blog/2013/07/27/rgb-to-hsv-in-glsl
vec3 hsv2rgb(vec3 c)
{
    vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
    vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
    return vec3(c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y));
}

// checks for hue equality based on threshold
bool equalHue(vec3 color1,vec3 color2){

    // convert to HSV to rotate Hue vector
    vec3 c1HSV= rgb2hsv(color1);
    vec3 c2HSV= rgb2hsv(color2);

    // constant treshold for equality check
    return (abs(c1HSV.x-c2HSV.x)<0.05f)?true:false;
}

// computes the opposite color in HSV by rotating the hue angle by 180 degrees
vec3 oppositeColor(vec3 color1,vec3 color2){    

    // convert to HSV to rotate Hue vector
    vec3 c1HSV= rgb2hsv(color1);
    vec3 c2HSV= rgb2hsv(color2);

    // hue of color1 + 180 and saturation/value from color2
    vec3 oppColor = vec3(mod(((c1HSV.x*360)+180), 360)/360, c2HSV.yz);

    // return RGB
    return hsv2rgb(oppColor);
}

// algorithm to calculate the new color from paper
vec3 huePreservingBlending(vec4 color1,vec4 color2){
    vec3 colorNew;
    if(equalHue(color1.rgb,color2.rgb)){
        colorNew = color1.rgb+(1-color.a)*color2.a*color2.rgb;
    }
    else{
       vec3 color2Prime = oppositeColor(color1.rgb,color2.rgb);
       colorNew = color1.rgb+(1-color.a)*color2.a*color2Prime;
       if(!equalHue(color1.rgb,colorNew)){
           vec3 color1Prime = oppositeColor(color2.rgb,color1.rgb);
           colorNew = color1Prime+(1-color.a)*color2.a*color2.rgb;
       }
    }  
    return colorNew;
}

void main() {
    // transform normalized device coordinates [-1,-1] to volume coordinate system [0,1]
    vec3 volPosition = (position+1)/2;

    float alphaB; // back voxel
    vec4 colorB;

    float x;
    float y;
    float z;

    // Front-to-Back compositing
    for(float i=0;i<depth;i++)
    {
        switch (orientation) {
            default:
            case 0: // top
                x = volPosition.x;
                y = volPosition.y;
                z = i/depth;
                break;
            case 1: // bottom
                x = 1.0f - volPosition.x;
                y = 1.0f - volPosition.y;
                z = (depth - i - 1)/depth;
                break;
            case 2: // left
                x = i/depth;
                y = volPosition.x;
                z = 1.0f - volPosition.y;
                break;
            case 3: // right
                x = (depth - i - 1) / depth;
                y = 1 - volPosition.x;
                z = 1.0f - volPosition.y;
                break;
            case 4: // front
                x = volPosition.x;
                y = i/depth;
                z = 1.0f - volPosition.y;
                break;
            case 5: // back
                x = 1 - volPosition.x;
                y = (depth - i - 1) / depth;
                z = 1.0f - volPosition.y;
                break;
        }
        colorB.a = texture(volume,vec3(x,y,z)).r;
        colorB.rgb = (colorB.a<regionSeperator)?regionColor1.rgb:regionColor2.rgb;
        color.rgb = huePreservingBlending(color,colorB);
        color.r=min(1,color.r);
        color.g=min(1,color.g);
        color.b=min(1,color.b);
        color.a=min(1,color.a + (1-color.a)*colorB.a*colorB.a);

        if(color.a==1){break;} // early ray termination
    }
}